如下文档翻译自
http://perl.plover.com/FAQs/Namespaces.html.en 如果你对perl的变量作用域有所疑惑，那么可参考本文。如有任何不明问题，也可在此问小女。
变量作用域
（一）包变量
$x = 1
这里，$x是个包变量。关于包变量，有2件重要的事情要了解：
1)假如没有其他申明，变量就是包变量；
2)包变量总是全局的。
全局意味着包变量在每个程序里总可访问到。在你定义了$x=1后，程序的任何其他部分，甚至在其他文件里定义的子程序，都能影响和修改$x的值。这点毫无例外；包变量总是全局的。
包变量被归类到族（叫做packages）。每个包变量的名字包括2部分。这2部分类似于变量自己的名字和族名。假如喜欢，你可以称呼美国副总统为'AL'，但对其全名'Al Gore'来讲，这确实太短。类似的，$x有一个全名，其形式如$main::x。主要部分是包限定词，类似于'Al Gore'里的'Gore'部分。Al Gore和AL Capone是不同的人，尽管他们都叫做'AL'。同样的，$Gore::Al和$Capone::Al是不同的变量，$main::x and $DBI::x也是不同的变量。
允许指定变量名的包部分，假如这样做，perl会明确知道你指的是哪个变量。但为简洁起见，通常不会指定变量的包限定词。
1.当前包
假如你仅说$x，perl假设你指的是当前包里的变量$x。什么是当前包？通常情况下是指main，但你可以改变当前包，在程序里这样写：
package Mypackage;
从这点开始，当前包就是Mypackage。当前包做的唯一事情是，在你没有指定包名时，它影响对包变量的解释。假如当前包是Mypackage，这时$x实际指$Mypackage::x。假如当前包是main，这时$x实际指$main::x。
假如你在编写一个模块，假设模块名称是MyModule，你可能会将如下行放在模块文件的顶部：
package MyModule;
从这里开始，你在模块文件里使用的所有包变量将位于包MyModule里，你可以非常放心，这些变量不会与程序其他部分的变量冲突。不必担心你和DBI的作者是否会使用同一个变量$x，因为变量会被区分开，一个是$MyModule::x，另一个是$DBI::x。
记住包变量总是全局的。即使你不在DBI包里，甚至即使你从来没听说过DBI包，也没什么能阻止你读取或写入$DBI::errstr。你不必做任何特殊事情。$DBI::errstr象所有包变量一样，是个全局变量，它可全局访问到；你要做的唯一事是用全名来获取它。甚至可以这样写：
package DBI;
$errstr = 'Ha ha Tim!';
这样就修改了$DBI::errstr。
2.关于包变量的补充
1)若包名为空，则等同于main。所以对任何x来讲，$::x等同于$main::x。
2)某些变量总是强迫位于main包里。例如，假如你提及%ENV,perl假设你指%main::ENV，即使当前包不是main。假如你想要%Fred::ENV，就必须明确申明，即使当前包是Fred。其他特殊的变量包括INC，所有的单标点符号变量名例如$_,$$, @ARGV，以及STDIN, STDOUT, 和STDERR。
3)包名，而非变量名，可以包含::。你可以命名变量为$DBD::Oracle::x。这意味着变量x位于包DBD::Oracle里；它与包DBD没有任何关系。Isaac Newton与 Olivia Newton-John无关，并且Newton::Isaac也与Newton::John::Olivia无关。尽管它们看起来都以Newton开头，但实际上这有点欺骗性。Newton::John::Olivia位于Newton::John包里，而不是Newton里。
这是你要了解的关于包变量的所有东西。
包变量是全局的，这意味着它是危险的，因为不能保证某个人不会在背后来破坏它们。在Perl 4之前，所有的变量都是包变量，这点令人不安。所以perl 5增加了新的非全局变量。
（二）词法变量
Perl里其他类型的变量叫做词法变量或私有变量，因为它们是私有的。它们有时也叫做my变量，因为总是以my来申明它们。你也许很想叫它们local变量，因为它们的影响被局限在程序的一小部分里。但不要那样做，因为其他人可能以为你在谈论perl的local操作符。当你想要一个local变量时，请想到my，而不是local。
my $x;
如上申明创建了一个新变量，叫做x，它对程序的大部分完全不可访问，大部分是指在申明变量的代码块之外的地方。这个块叫做变量作用域。假如变量未在任何块里申明，它的作用域就是从申明它的地方开始，到文件的结尾。
也可以申明和初始化一个my变量，这样写：
my $x = 119;
也能同时申明几个变量：
my ($x, $y, $z, @args) = (5, 23, @_);
如下示例展示私有变量在哪里会很有用。考虑这个子程序：
sub print_report {
@employee_list = @_;
foreach $employee (@employee_list) {
$salary = lookup_salary($employee);
print_partial_report($employee, $salary);
}
}
假如lookup_salary碰巧也使用了名为$employee的变量，这个变量名和print_report使用的一样，事情就会变得糟糕。负责print_report和lookup_salary的2个程序员必须协作，以确保他们不使用相同的变量名。这点是痛苦的。事实上，即使是在一个中等大小的项目里，这点也令人无法忍受。
解决方法是：使用my变量：
sub print_report {
my @employee_list = @_;
foreach my $employee (@employee_list) {
my $salary = lookup_salary($employee);
print_partial_report($employee, $salary);
}
}
my @employee_list创建一个新的数组变量，它在print_report函数之外完全不可访问。 my $employee创建一个标量变量，它在foreach循环外完全不可访问。你不必担心程序里的其他函数会破坏这些变量，因为它们没这个能力；它们不知道这些变量在哪里，因为变量的名字在my申明的作用域之外有不同的意义。my变量有时也叫做词法变量，因为它们的作用域仅仅依赖于程序文本自身，不依赖于执行细节，例如以什么顺序来执行什么。仅通过检查源代码，就可以弄清楚它们的作用域。无论何时你看到一个变量，请在同一代码块里的先前位置找my申明。假如找到了，你可以确认该变量在代码块之外不可访问。假如在最内层的代码块里没有找到my声明，那就到上一层块里找，依此类推，直到找到为止。假如任何地方都没有my申明，那么这个变量是个包变量。
my变量并非包变量。它们不是包的一部分，并且没有包限定词。当前包不会因为变量的解释方式而受到影响。如下是个例子：
my $x = 17;
package A;
$x = 12;
package B;
$x = 20;
# $x is now 20.
# $A::x and $B::x are still undefined
在顶部的my $x=17的申明创建了一个新的名为x的词法变量，它的作用域持续到文件结尾。$x的新意义覆盖了默认的意义，默认意义是指$x是当前包的一个包变量。
package A改变了当前包，但因为$x指向了词法变量，而不是包变量，$x=12不会对$A::x有任何影响。类似的，在package B后，$x=20修改了词法变量，而不是任何包变量。
在文件结尾，词法变量$x值为20，包变量$main::x, $A::x, 和$B::x仍未定义。假如要使用它们，仍须通过全名来访问它们。
必须记住的是：
包变量是全局变量。
对私有变量，必须使用my申明。
1. local和my
几乎每个人都知道，有个local函数，它对本地变量有些影响。它到底是什么呢，与my有关系吗？答案简单而奇怪：
my创建本地变量，然而local不这样。
首先，local $x实际做的事是：它存储包变量$x的当前值在一个安全的地方，然后用一个新值替换它，假如没有指定新值，就使用undef代替。当控制离开当前块时，它也会恢复$x的旧值。它影响的是包变量，这个包变量获取了本地值。但包变量总是全局的，local申明的包变量亦无例外。为了显示其区别，请看这个：
$lo = 'global';
$m = 'global';
A();
sub A {
local $lo = 'AAA';
my $m = 'AAA';
B();
}
sub B {
print "B ", ($lo eq 'AAA' ? 'can' : 'cannot') ,
" see the value of lo set by A.\n";
print "B ", ($m eq 'AAA' ? 'can' : 'cannot') ,
" see the value of m set by A.\n";
}
结果会打印：
B can see the value of lo set by A.
B cannot see the value of m set by A.
发生了什么？在A函数里的local申明，给包变量$lo赋予了一个新的临时值AAA。旧值global会被存储起来，直到A返回，但在这点之前，A调用了B。B访问$lo的内容没有问题，因为$lo是包变量，包变量总是全局可见的，所以它能见到A设置的AAA值。
与之对照的是，my申明创建了一个新的词法作用域的变量叫做$x，它仅仅在A函数里可见。在A之外，$m保留它的旧意义：它指向包变量$m；其值仍是global。这是B所见到的变量。它不会见到AAA值，因为那个变量是个词法变量，仅仅存在于A里。
2.local有何好处？
因为local实际不创建本地变量，它并非很有用。在上述示例里，假如B碰巧修改了$lo的值，这样A设置的值就被覆盖掉。这点我们确实不想它发生。我们希望每个函数有它自己的变量，它们不会被其他函数触及到。这就是my所能做到的。
为什么会有local呢？答案90%是因为历史原因。早期的perl版本仅有全局变量。local非常容易执行，它作为对本地变量问题的局部解决方案而增加到perl4里。后来在perl5里做了更多工作，真正的本地变量被添加到该语言里。不同于local，新的本地变量以单词my来申明。之所以选择my，是因为它暗示着隐私，也因为它非常短；短小的单词也许会鼓励你使用它来代替local。my也比local运行更快。
何时使用my，以及何时使用local呢？
答案很简单：总使用my，绝不要使用local。
3.my变量的其他特性
每次控制抵达my申明，perl创建一个新的，初始的变量。例如，如下代码打印x=1 50次：
for (1 .. 50) {
my $x;
$x++;
print "x=$x\n";
}
每次遍历循环时，你得到一个新的$x，其值初始化为undef。
假如申明在循环之外，控制只会通过它一次，所以这里就只有一个变量：
{ my $x;
for (1 .. 50) {
$x++;
print "x=$x\n";
}
}
这会打印x=1, x=2, x=3, ... x=50.
可以利用这点来玩个游戏。假设有个函数，它需要从一个调用到下一个调用中记住某个值。例如，考虑一个随机数产生器。典型的随机数产生器（类似perl的rand函数）有个种子在其中。种子就是一个数。当请求随机数产生器来获取随机数时，该函数基于种子来执行某些运算，然后返回结果。它也会存储该结果，并将其作为下一次函数调用的种子。
如下是典型代码：
$seed = 1;
sub my_rand {
$seed = int(($seed * 1103515245 + 12345) / 65536) % 32768;
return $seed;
}
典型的输出：
16838
14666
10953
11665
7451
26316
27974
27550
这里有个问题，因为$seed是个全局变量，那意味着我们必须担忧某个人可能无意中修改它。或者别人有意破坏它，这就影响了程序的结果。假如该函数用于赌博程序中，并且别人破坏了它的随机数产生器，你想想会发生什么？
但是我们不能在函数里申明$seed为my变量：
sub my_rand {
my $seed;
$seed = int(($seed * 1103515245 + 12345) / 65536) % 32768;
return $seed;
}
假如这样做了，当每次调用my_rand时，$seed会被初始化为undef。我们实际需要的是，在每次调用my_rand时，$seed会保留其值。
如下是解决方法：
{ my $seed = 1;
sub my_rand {
$seed = int(($seed * 1103515245 + 12345) / 65536) % 32768;
return $seed;
}
}
申明在函数之外，所以它仅仅在程序编译时执行一次，而不是每次函数调用时都执行。但它是个my变量，并且其位于代码块里，所以它仅对块里的代码可见。my_rand是块里的唯一其他东西，所以$seed仅可被my_rand函数访问。
4.关于my变量的补充
1)不能对以标点符号命名的变量使用my申明，例如_, @_, 或$$。也不能对后台引用的变量$1, $2, ... 使用my申明。my的作者认为那会把事情搞糟。
2)明显的，不能申明my $DBI::errstr，因为那会有冲突：它认为包变量$DBI::errstr是个词法变量。但是可以申明local $DBI::errstr；它存储local $DBI::errstr的当前值，并在代码块结束处恢复它。
3)在perl 5.004及更高版本里，可以这样写：
foreach my $i (@list) {
它限制$i在循环范围内。类似的，
for (my $i=0; $i<100; $i++) {
限制了$i在for循环里。
（三）变量申明
假如你在编写某个函数，并且你想要它有私有变量，就必须使用my来申明变量。假如忘记了，会发生什么事？
sub function {
$x = 42; # Oops, should have been my $x = 42.
}
在该情形下，你的函数修改了全局包变量$x。假如你在其他地方要用到那个包变量，那对程序将是灾难。
最近版本的perl有针对这点的保护选项，你可以激活它。假如放置：
use strict 'vars';
在程序的顶部，perl将要求包变量有明确的包限定词。$x=42里的$x没有这样的限定词，所以程序甚至不会通过编译；代替的，编译器会异常中断，并输出如下错误消息：
Global symbol "$x" requires explicit package name at ...
假如你希望$x是个私有my变量，你可以回头增加my。假如你确实想使用全局包变量，你能回头改变它为：
$main::x = 42;
或其他相应的包。
use strict还有其他的检测选项，请看perldoc strict的更多细节。
现在假设你在编写Algorithms::KnuthBendix模块，你想使用strict vars保护模式，但假如任何时候你需要一遍又一遍的敲入$Algorithms::KnuthBendix::Error，你会觉得很烦。
你可以告诉strict vars生成一个例外：
package Algorithms::KnuthBendix;
use vars '$Error';
这样就在你使用短名字$Error时，避免了包变量$Algorithms::KnuthBendix::Error导致的strict vars失败。
如下写法，也可以在某个代码块里关闭strict vars：
{ no strict 'vars';
# strict vars is off for the rest of the block.
}
（四）总结
包变量总是全局的。它们有一个名字和一个包限定词。可以忽略包限定词，这样perl会使用默认的包，默认包可由package申明设定。对私有变量，请使用my。不要使用local,它已过时。
避免使用全局变量，因为它难以确保程序的2部分不会错误的使用对方的变量。
为了避免意外使用全局变量，请在程序里使用use strict 'vars'。它会检查并确保所有的变量要么是申明为私有的，要么明确使用了包限定词，要么明确使用use vars来申明。
（五）关于'our'的补充
perl 5.6.0介绍了一个新的our(...)申明。它的语法与my()相同，它是use vars的代替品。
如果不深究细节，our()就类似于use vars；它的唯一影响是申明变量，以便它们免除strict 'vars'的检查。然而相对于use vars，它可能有2个优势：语法不那么怪异，影响是词法作用域。也就是说，它让stict检查失效的范围仅仅在当前块之内：
use strict 'vars';
{
our($x);
$x = 1; # 这里使用全局变量$x没问题
}
$x = 2; # 这里使用$x通常引起编译时错误
所以使用use vars '$x'申明时，可以在任何地方使用全局变量$x。our($x)仅仅允许在程序的某些块里申明全局变量$x，假如意外的在其他地方使用它，仍会导致错误。
--------------------------------------------------------------------------------
flw 回复于：2005-09-16 12:06:02
^_^
不错不错！
--------------------------------------------------------------------------------
兰花仙子 回复于：2005-09-16 12:52:50
[quote:3123c15630="flw"]^_^
不错不错！[/quote:3123c15630]
谢谢斑竹夸奖，
ops:
--------------------------------------------------------------------------------
大大狗 回复于：2005-09-27 15:43:29
呵呵～我也来支持
--------------------------------------------------------------------------------
snojasper 回复于：2005-09-29 15:16:34
请问仙子：在perl中有哪些内置函数？？
--------------------------------------------------------------------------------
兰花仙子 回复于：2005-09-29 15:18:31
[quote:d9cbc85e0d="snojasper"]请问仙子：在perl中有哪些内置函数？？[/quote:d9cbc85e0d]
Perl程序设计中常用的函数
指令:#
说明:注示符号Remark宣告
示例:#这是一个注示说明
--------------------------------------------------------------------------------
指令:print
语法:print Filehandle LIST
说明:这个Filehandle可以看作在I(INPUT)/O(OUTPUT)之间的一个桥梁,可以利用FILEHANDLE来做出数据读入写
出的动作.STDIN是代表从哪连输入数据,例如从电脑的键盘输入;STDOUT是代表从哪连输出数据;例如从电脑的屏
幕输出;STDERR是代表从哪连输出错误的数据,例如从电脑的屏幕输出.而在PERL语言中有三个标准FILEHANDLE:
1.STDIN(标准输入):是代表STDIN的FILEHANDLE
2.STDOUT(标准输出):是代表STDOUT的FILEHANDLE
3.STDERR(标准错误输出):是代表STDERR的FILEHANDLE如果要使用其他FILEHANDLE的时候,就要用OPEN这个函数
来打开一个FILEHANDLE,我们可以用PRINT这个函数LIST的数据输出给FILEHANDLE.在为大家介绍PRINT这个函数
之前,先让我们来看看PRINT函数中特殊打印字符:
符号 其作用
\n 换行 new line
\r 光标换行 return
\t tab键
\f 换页 form feed
\b 退回一格
\v 垂直tab键
\a 响铃Bell
\e escape键
\007 十进制ascii码
\xff 十六进制码
\c[ 控制字符
示例: print STDOUT"足球世界\n";
将"足球世界"加上换行显示在屏幕上.
语法: print LIST
说明: 如果省略Filehandle的话,就会把Filehandle内定为STDOUT.也就是会将LIST的数据内容显示在屏幕上.
示例: $url="
www.netease.net/~peishan";
print"足球世界$url\n";
在屏幕上将会出现"足球世界
www.netease.net/~peishan",如果想要让双引号内的变量失效,可以在变量
的前面加上\符号.例如:
print"足球世界\$url";
这样它就显示:"足球世界$url"
语法: print
说明: 同省略Filehandle和LIST的话,就会以STDOUT为Filehandle,并会输出$_这个内定输出变量的数据内容.
如果$_变量是一个空字符串的话,就会显示出一个空字符串.
示例: $_="足球世界\n";
print;
就会将"足球世界"加上换行显示在屏幕上
--------------------------------------------------------------------------------
指令: printf
语法: printf Filehandle LIST
说明: 在perl语言中也提代C语言中printf的语法,用法和C语言中的用法一模一样.如果把Filehandle省略的话
,也一样会把STDOUT当成是内定的Filehandle.在为大家介绍printf函数之前,先让我们来看看printf函
数中变换符号的字符.
符号 其作用
%c 字符
%s 字符串
%d 整数
%f 浮整数
%h 十六进制码
%o 八进制码
示例：printf("chomod%d%s\n","711""cgi");
会将chmod 711 cgi加上换行显示于屏幕上。
--------------------------------------------------------------------------------
指令：chop
语法：chop($url)
说明：把最后一个字符删除。
示例：$url="linux.cqi.com.cn/~milan/";
chop($url);
这时$url="linux.cqi.com.cn/~milan"
而这两行也可以写成chop($url="linux.cqi.com.cn/~milan/");
--------------------------------------------------------------------------------
指令：split
语法：split(/pattern/,$text,limit)
其中/pattern是文字处理的模式，而limit是代表要分割的个数，一般可以省略。
说明：用一个指定的文字处理模式来分割$text字符串。
示例：$text="Michael,Gevin,Mike";
@name=split(/,/,$text); #这时@name=("Michael","Gevin","Mike");
($a,$b,$c)=split(/,/,$text); #这时$a="Michael";$b="Gevin";$c="Mike";
@name=split(/,/,$string,2); #这时@name=("Michael","Gevin");
在传送CGI应用程序数据的时候会先将数据编码，其中会将FORM中第个数据字段
的数据内容用&这个符号隔开，所以在解码的时候就要以&这个符号为分割的字
符，将每个数据字段分割出。例如：
$text="Mike=A&Michael=B";
@name=split(/&/,$text); #这时@name=("Mike=A","Michael=B");
而数据字段的名称和这个数据字段的值是用=这个符号来隔开，如果想取得数据
字段的名称和所对应的值的话，就用要=这个符号来分割数据字段，例如：
$name="Mike=Michael"；
($name1,$name2)=split(/=/,$list); #这时$name1="Mike";$name2="Michael";
--------------------------------------------------------------------------------
指令：keys
语法：keys(%array)
说明：取出关联数组%ARRAY中全部的key。
示例：%NAME=(1,"mike",2,"michael");
@readkey=keys(%NAMES); #这时@readkey=(1,2);
--------------------------------------------------------------------------------
指令：values
语法：values(%array)
说明：取出关联数组%ARRAY中全部的value。
示例：%NAMES=(1,"mike",2,"michael");
@readval=values(%NAMES); #这时@readval=("mike","michael");
--------------------------------------------------------------------------------
指令：reverse
语法：reverse(@array)
说明：将数组@array中的元素由后到前重新排列。
示例：@back=("A","B","C","D","E");
@back=reverse(@back); #这时@back=("E","D","C","B","A");
--------------------------------------------------------------------------------
指令：sort
语法：sort(@array)
说明：将数组中的元素由小到大排序，如果要由大到小排序的话，要加上reverse这个函数。
示例：
@abc=("d","b","c","a");
@abc=sort(@abc); #这时@abc=("a","b","c","d");
@abc=(reverse sort@abc); #这时@abc=("d","c","b","a");
这个语法也可以写成@abc=(reverse sort(@abc));
@number=(5,2,10);
@number=sort(@number);
上面示例用sort函数来排序数值的时，会出差错，因此要用下面到下面这一句。
@number=(sort{$a<=>$b}@number); #这时@number=(2,5,10);
--------------------------------------------------------------------------------
指令：length
语法：length($string)
说明：求出字符串$string的字节(bytes)值。
示例：$string="
erl5";
$size=length($string); #这时$size=5;
--------------------------------------------------------------------------------
指令：substr
语法：substr($string,offset,length)
offset代表起始字符的位置,length代表引用的字符串长度，如果省略length则代表从起始值到字符串
的最后一个字符长度。而offset如果是负值的话，就会从字符串右边开始指定字符。
示例：$s=substr("perl5",2,2); #这时$s="rl";
$s=substr("perl5",2); #这时$s="rl5";
$s=substr("perl5",-2,2); #这时$s="er";
--------------------------------------------------------------------------------
指令：index
语法：index($string,$substring,position)
$substring是要寻找的字符；position代表从哪一个位置开始寻找，假如省略position就从头开始找
起。
说明：返回所要找寻的字符在一字符串$string中的位置，如果在字符串中找不到字符的话，则会返回-1这个
值。
示例：$s=index("perl5","p"); #这时$s=0
$s=index("perl5","l",2); #这时$s=3
$s=index("perl5","perl"); #这时$s=-1
--------------------------------------------------------------------------------
指令：push
语法：push(@array,$string)
说明：在数组@array的最后附加新的元素 ($string)到数组@array中。
示例：@array=("one","two");
push(@array,"three"); #这时$@array=("one","two","three")
--------------------------------------------------------------------------------
指令：pop
语法：pop(@array)
说明：将数组(@array)的最后一个元素删除，并将删除的元素返回。
示例：@array=("one","two");
$rm=pop(@array); #这时@array=("one");而$rm="two";
--------------------------------------------------------------------------------
指令：unshift
语法：unshift(@array,$string)
说明：在数组@array的第一个元素前附加新的元素$string到数组@array中。
示例：
@array=("one","two");
unshift(@array,"three"); #这时@array=("three","one","two")
--------------------------------------------------------------------------------
指令：shift
语法：shift(@array)
说明：将数组@array的第一个元素删除，并将删除的元素返回。
示例：@array=("one","two");
@rm=shift(@array): #这时@array=("two");而$rm="one";
--------------------------------------------------------------------------------
指令：join
语法：join($string,@array)
说明：在一数组@array的元素之间加上一指定的字符$string,并将结果返回。
示例：
@array=("one","two","three");
$total=join(":",@array); 这时$total="one:two:three";
--------------------------------------------------------------------------------
指令：grep
语法：grep(/pattern/,@array)
说明：将合文字处理模式(regular expression)的数组元素找出来。
示例：
@array=("one","on","in");
$count=grep(/on/,@array); #这时$count=2
@result=grep(/on/,@array);#这时@result=("one","on");
--------------------------------------------------------------------------------
指令：hex
语法：hex($string)
说明：将十六进制的数值转成十进制。
示例：
$decimal=hex("ff"); 这时$decimal=255;
--------------------------------------------------------------------------------
指令：rand
语法：rand($interger)
说明：常和函数srand搭配来取得一随机数，如果没有先宣告stand函数的话，则取出的常数值是一个固定值。
这个语法会返回一个介于0和$interger之间的数值，如果$interger省略的话，则会返回一个介于0和1
的数值。
示例：
srand; #要先宣告srand函数，才能产生随机数的效果
$int=rand(10); #$int的值会大于0而且小于10如果希望产生的乱数是整数的话，就要再加上int
#这个函数
$int=int(rand(10)); #$int的值是一个整数，且值在0和9之间
--------------------------------------------------------------------------------
指令：localtime
语法：localtime(time)
说明：可返回九个有关时间的元素，在写CGI应用程序的时候常会用到系统的时间，所以在此会详细介绍这个函
数的用法。
示例：
($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst)=localtime(time);
其中：
$sec代表秒数[0,59] $min代表分数[0,59]
$hour代表小时数[0,23] $mday代表是在这个月的第几天[1,31]
$mon代表月数[0,11],要将$mon加1之后，才能符合实际情况。
$year从1990年算起的年数
$wday从星期六算起，代表是在这周中的第几天[0-6]
$yday从一月一日算起，代表是在这年中的第几天[0,365]
$isdst只是一个flag
知道这些变量之后，就可以在CGI应用程序中拿来应用了。此外，也可以用下面这一行指令在UNIX系统下
取得系统的时间。为了避免错误发生，最好用绝对路径的方法来取得系统时间，如果绝对路径不清楚的
话可以用"which data"这个指令来得知。最后要提字符的话，就不能正确执行系统的程序了。
$data='/usr/bin/data';
而在perl5版本中，也可以用下面这一行指令来取得系统时间。
$data=localtime(time);
--------------------------------------------------------------------------------
指令：die
语法：die LIST
说明：会把LIST字符串显示出来，并退出程序。常常和$!这个代表错误信息变量一起使用。
示例：
open(FILE,"$filename")||die "不能打开文件$!\n;
如果打开文件失败的话，就会显示出错误的信息，之后再退出程序。
--------------------------------------------------------------------------------
指令：open
语法1：open(filehandle,"$filename")
其中$filename是一个指定打开的文件名。
说明：这是一个很常用的函数，可用于文件的打开(read only)。在CGI程序设计中常常会打开一个文件来读取
数据，所以笔者会详加说明这一个函数相关用法。
这个filehandle可把它看作在I(INPUT)/O(OUTPUT)之间的一个桥梁，可以利用FILEHANDLE来作出数据读
入写出的动作。开始可用OPEN这个函数来打开一个指定的文件，接下来可以用<filehandle>来读取
所打开文件的数据内容，最后一定要用close这个函数来关闭这个之前打开的filehandle。要注意的是在
CGI程序定作中，当用OPEN这个函数来打开一个文件时，一定要在打开文件前加上文件所在的绝对路径名
称。
示例：
$filename="usr/abc.txt";
open(FILE,"$filename")||die"不能打开文件$filename\n;
#将<file>数据指定给纯变量$line(一行一行地)
while($line=<file>){
print"$line";
}
close(file);
就会把abc.txt这个文件的内容显示出来。
语法2：open(filehandle,"<$filename")
说明： 这个语法也可以打开一个存在的文件(read only)。
示例：
$filesname="usr/abc.txt";
open(file,"<$filename")||die"不能打开文件$filename\n";
@array=<file> #将<file>全部的数据内容都指定给数组@array
close(file);
print "@array";
也会把abc.TXT这个文件的内容显示出来。
语法3: open(filehandle,">$filename")
说明： 建立一个新的文件(write only),如果已经存在这个文件了，就会把旧文件名覆盖掉。并可用print fi
lehandle的方式将数据到所打开的文件中。
示例：
$filename="/usr/abc.txt";
open(file,">$filename")||die"不能打开文件$filename\n;
print file"this is a new line1\n; #\n是换行字符
print file"this is a new line2\n;
close(file);
会打数据存在一个新文件中。
语法4: open(filehandle,">>$filename")
说明： 数据用附加的方式定入一文件(write only)，如果指定的文件名不存在的话就会建立一个新的文件。
示例：
$filename="/path/abc.txt";
open(file,">>$filename")||die"不能打开文件$filename\n";
print file "this is a new line1\n";
print file "this is a new line2\n";
close(file);
会打数据附加(append)到一个文件(abc.txt)中。
语法5
pen(filehandle,"|unix command")
说明：就会把在filehandle的数据输入给unix的指令来作处理。
示例：
$mailprog="/usr/ucb/mail"; #unix系统上的寄信程序(一定要加绝对路径)
$who="
tryfly@163.net";
$open(file,"|$mailprog$who")||die"打开失败\n";
print file"I love you!\n";
print file"I want to see you.\n";
close(file);
就会通过unix系统mail的程序，将FILE这个FILEHANDLE的数据内容寄给$who这个变量所指定的收信人。
我们可以利用open这个函数来设计一个来信批评CGI应用程序，在本书中的下一章中会有详细的介绍。
--------------------------------------------------------------------------------
指令：close
用法：close(filehandle)
说明：用open这个函数来打开一个filehandle之后，一定要用close批这个函数把所打开的filehandle关闭。
示例：
open(filehandle,"$filename");
close(filehandle);
--------------------------------------------------------------------------------
指令：pack
语法：pack("指定的格式",list)
说明：pack这个函数会将一个list变成所指定的二进制数据格式。在CGI程序分割解码过程中，会用到pack这
个函数,所以笔者在此简单介绍这个函数的用法。
示例：
$string=pack("c",65); #这时$string="a";
将65这个ascii码转换成一个unsigned字符，其中c就是指定要转换成unsigned字符的意思。
--------------------------------------------------------------------------------
指令：read
语法：read(filehandle,$string,length)
其中length是代表读入字符串的长度(bytes)。
说明：用read这个函数把filehandle中的数据依指定的字符串长度读入之后指派给$string这个变量。在cgi程
序分割解码过程中，如果FORM的传送方式是设定为POST的话，就会将传送的数据设定为标准输入，所以
会将数据内容指定给STDIN这个标准输入的filehandle，而CGI环境变量$env{'content_length'}就是代
表使用者送出数据内容的长度，因此我们要用read这个函数来取得使用者送出的数据内容。
示例：
read(stdin,$buffer,$env{'content_length'});
就会将stdin这个标准输入filehandle中的数据依指定的字符串长度读入，再指派给$buffer这个变量。
--------------------------------------------------------------------------------
指令：exit
语法：exit
说明：退出执行的程序。
示例：
print"i love cgi\n";
exit;
显示完"i love cgi"以后，将退出这个程序。
